Demonstration of Operator Algebras and Kron

Let M, D, F be matrix-based, diagonal-matrix-based, and function-based SciMLOperators respectively. Here are some examples of composing operators in order to build more complex objects and using their operations.

using SciMLOperators, LinearAlgebra
N = 4
function f(v, u, p, t)
    u .* v
end
function f(w, v, u, p, t)
    w .= u .* v
end

u = rand(4)
p = nothing # parameter struct
t = 0.0     # time

M = MatrixOperator(rand(N, N))
D = DiagonalOperator(rand(N))
F = FunctionOperator(f, zeros(N), zeros(N); u, p, t)

FunctionOperator(4 × 4)

Then, the following codes just work.

L1 = 2M + 3F + LinearAlgebra.I + rand(N, N)
L2 = D * F * M'
L3 = kron(M, D, F)
L4 = lu(M) \ D
L5 = [M; D]' * [M F; F D] * [F; D]

((((MatrixOperator(4 × 4) * MatrixOperator(4 × 4)) + (DiagonalOperator(4 × 4) * FunctionOperator(4 × 4))) * FunctionOperator(4 × 4)) + (((MatrixOperator(4 × 4) * FunctionOperator(4 × 4)) + (DiagonalOperator(4 × 4) * DiagonalOperator(4 × 4))) * DiagonalOperator(4 × 4)))

Each L# can be applied to AbstractVectors of appropriate sizes:

v = rand(N)
w = L1(v, u, p, t) # == L1 * v

v_kron = rand(N^3)
w_kron = L3(v_kron, u, p, t) # == L3 * v_kron

64-element reshape(transpose(::Matrix{Float64}), 64) with eltype Float64:
 0.3986803710628615
 0.26325509920215007
 0.16202219065568818
 0.062400611533896644
 0.024427223295104352
 0.048666457482548546
 0.012334698935135665
 0.0061084066420570545
 0.1471433709834386
 0.1699603987558361
 ⋮
 0.010143671908284527
 0.21938924536615312
 0.2078310108076943
 0.11274530194107688
 0.049129416165748147
 0.025809818535701003
 0.08865444297250602
 0.03276942028892786
 0.02728289734684551

For mutating operator evaluations, call cache_operator to generate an in-place cache, so the operation is nonallocating.

α, β = rand(2)

# allocate cache
L2 = cache_operator(L2, u)
L4 = cache_operator(L4, u)

# allocation-free evaluation
L2(w, v, u, p, t) # == mul!(w, L2, v)
L4(w, v, u, p, t, α, β) # == mul!(w, L4, v, α, β)

4-element Vector{Float64}:
 -0.04519344715180344
 -0.2381521857142033
 -0.9342944375644786
  1.3328164467862595