Demonstration of Operator Algebras and Kron

Let M, D, F be matrix-based, diagonal-matrix-based, and function-based SciMLOperators respectively. Here are some examples of composing operators in order to build more complex objects and using their operations.

using SciMLOperators, LinearAlgebra
N = 4
function f(v, u, p, t)
    u .* v
end
function f(w, v, u, p, t)
    w .= u .* v
end

u = rand(4)
p = nothing # parameter struct
t = 0.0     # time

M = MatrixOperator(rand(N, N))
D = DiagonalOperator(rand(N))
F = FunctionOperator(f, zeros(N), zeros(N); u, p, t)

FunctionOperator(4 × 4)

Then, the following codes just work.

L1 = 2M + 3F + LinearAlgebra.I + rand(N, N)
L2 = D * F * M'
L3 = kron(M, D, F)
L4 = lu(M) \ D
L5 = [M; D]' * [M F; F D] * [F; D]

((((MatrixOperator(4 × 4) * MatrixOperator(4 × 4)) + (DiagonalOperator(4 × 4) * FunctionOperator(4 × 4))) * FunctionOperator(4 × 4)) + (((MatrixOperator(4 × 4) * FunctionOperator(4 × 4)) + (DiagonalOperator(4 × 4) * DiagonalOperator(4 × 4))) * DiagonalOperator(4 × 4)))

Each L# can be applied to AbstractVectors of appropriate sizes:

v = rand(N)
w = L1(v, u, p, t) # == L1 * v

v_kron = rand(N^3)
w_kron = L3(v_kron, u, p, t) # == L3 * v_kron

64-element reshape(transpose(::Matrix{Float64}), 64) with eltype Float64:
 0.17587949958864915
 0.24080987716575064
 0.06978955396022153
 0.2294651595055224
 0.1464229557366228
 0.09034919314615195
 0.051904981045798326
 0.19882805784804497
 0.0363315413110914
 0.1110629112237046
 ⋮
 0.12951878032348596
 0.0979871013420433
 0.2636476564450818
 0.04482161014834026
 0.10446910640084026
 0.15020903328644844
 0.19279535492249217
 0.02977897650660842
 0.11385860492038646

For mutating operator evaluations, call cache_operator to generate an in-place cache, so the operation is nonallocating.

α, β = rand(2)

# allocate cache
L2 = cache_operator(L2, u)
L4 = cache_operator(L4, u)

# allocation-free evaluation
L2(w, v, u, p, t) # == mul!(w, L2, v)
L4(w, v, u, p, t, α, β) # == mul!(w, L4, v, α, β)

4-element Vector{Float64}:
  0.2126910473839107
  0.05440645251592639
 -0.16029404131902344
  0.21195853956838176